Anti-cheat did not un-install

Anti-Cheat Service Manual Uninstall Script

  • Make sure you have restarted your computer since the last time you played Bloodhunt.
  • Copy the script below (Mark it all, right click and press "Copy")

  • @ECHO OFF

    REM A big thank you to Jeroen Baert, who helped debug this issue!

    ECHO Manual uninstall for anti-cheat services...

    REM Check for admin permissions. Without admin permissions, this script is powerless.
    net.exe session 1>NUL 2>NUL && (
    GOTO as_admin
    ) || (
    GOTO not_admin
    )

    ECHO Looking for installed components...

    :as_admin
    SET "usermode_service_name=AntiCheatExpert Service"
    SET "kernel1_service_name=ACE-BASE"
    SET "kernel2_service_name=ACE-GAME"
    SET "folder_name=%ProgramW6432%\AntiCheatExpert"
    SET "folder_name2=%ProgramData%\AntiCheatExpert"
    SET "SystemPath=%SystemRoot%\System32"
    If "%PROCESSOR_ARCHITEW6432%" == "AMD64" SET "SystemPath=%SystemRoot%\Sysnative"
    SET "kernel1_sys=%SystemPath%\drivers\ACE-BASE.sys"
    SET "kernel2_sys=%SystemPath%\drivers\ACE-GAME.sys"
    SET "reg_del_file=%temp%\ace_clear.reg"
    SET /A LOCAL_COUNTER=0

    SET "found_something="
    sc.exe query "%usermode_service_name%" >NUL
    IF %ERRORLEVEL% EQU 0 (
    SET "found_something=y"
    )
    sc.exe query "%kernel1_service_name%" >NUL
    IF %ERRORLEVEL% EQU 0 (
    SET "found_something=y"
    )
    sc.exe query "%kernel2_service_name%" >NUL
    IF %ERRORLEVEL% EQU 0 (
    SET "found_something=y"
    )
    IF EXIST "%folder_name%" (
    SET "found_something=y"
    )
    IF EXIST "%folder_name2%" (
    SET "found_something=y"
    )
    IF EXIST "%kernel1_sys%" (
    SET "found_something=y"
    )
    IF EXIST "%kernel2_sys%" (
    SET "found_something=y"
    )

    IF defined found_something (ECHO Install found...) else (GOTO no_services)

    ECHO Stopping services... this can take a long time (2-3 minutes)!

    sc.exe stop "%usermode_service_name%" 1>NUL 2>NUL
    timeout /t 10 /nobreak > NUL
    sc.exe delete "%usermode_service_name%" 1>NUL 2>NUL

    RMDIR /s /q "%folder_name%" 1>NUL 2>NUL
    IF EXIST "%folder_name%" GOTO deleting_fail

    RMDIR /s /q "%folder_name2%" 1>NUL 2>NUL
    IF EXIST "%folder_name2%" GOTO deleting_fail

    ECHO Windows Registry Editor Version 5.00 >"%reg_del_file%"
    ECHO. >>"%reg_del_file%"
    ECHO [-HKEY_CURRENT_USER\SOFTWARE\AppDataLow\AntiCheatExpert] >>"%reg_del_file%"
    ECHO [-HKEY_USERS\.DEFAULT\SOFTWARE\AppDataLow\AntiCheatExpert] >>"%reg_del_file%"
    regedit.exe /s "%reg_del_file%" 1>NUL 2>NUL
    DEL "%reg_del_file%"

    :waitloop
    SET /A LOCAL_COUNTER=LOCAL_COUNTER+1
    timeout /t 5 /nobreak >NUL

    IF %LOCAL_COUNTER% EQU 28 (
    REM Service is not closing, give it a nudge
    REM Don't force-stop ace-base, only ace-game, or it might cause instability
    sc.exe stop "%kernel2_service_name%" 1>NUL 2>NUL
    )

    REM Equal to 2.67 min
    IF %LOCAL_COUNTER% GEQ 32 (
    REM Windows is not releasing the services, give up...
    GOTO :EOF
    )

    sc query "ACE-BASE" | find "RUNNING" >NUL
    IF %ERRORLEVEL% EQU 0 (
    GOTO waitloop
    )
    sc query "ACE-GAME" | find "RUNNING" >NUL
    IF %ERRORLEVEL% EQU 0 (
    GOTO waitloop
    )

    sc.exe delete "%kernel1_service_name%" 1>NUL 2>NUL
    sc.exe delete "%kernel2_service_name%" 1>NUL 2>NUL

    ECHO Deleting services...

    REM Retry delete until Windows releases the file handle
    REM Re-try delete of service one...
    SET /A LOCAL_COUNTER=0

    :deleteloopone
    SET /A LOCAL_COUNTER=LOCAL_COUNTER+1
    timeout /t 5 /nobreak >NUL

    IF %LOCAL_COUNTER% EQU 36 (
    ECHO Failed delete, giving up.
    GOTO :deleting_fail
    )

    del /Q "%kernel1_sys%" 1>NUL 2>NUL
    IF EXIST "%kernel1_sys%" GOTO deleteloopone

    REM Re-try delete of service two...
    SET /A LOCAL_COUNTER=0

    :deletelooptwo
    SET /A LOCAL_COUNTER=LOCAL_COUNTER+1
    timeout /t 5 /nobreak >NUL

    IF %LOCAL_COUNTER% EQU 36 (
    ECHO Failed delete, giving up.
    GOTO :deleting_fail
    )

    del /Q "%kernel2_sys%" 1>NUL 2>NUL
    IF EXIST "%kernel2_sys%" GOTO deletelooptwo

    ECHO All done - anti-cheat services are removed. Have a nice day!
    pause

    GOTO :EOF

    :no_services
    ECHO No installed components found. All is well!
    pause
    GOTO :EOF

    :deleting_fail
    ECHO Failed to delete all components. Please try restarting your computer and run this again.
    pause
    GOTO :EOF

    :not_admin
    ECHO You need to run this as administrator. Right-click the script and choose "Run as Administrator"
    pause

     

  • Open a blank Notepad
  • Right click in the notepad and press Paste
  • Save the notepad as "ACE_Uninstall.bat" on your desktop
  • Go to your desktop and Right-click the script and choose “Run as Administrator
  • It will run through a check to see what needs to be uninstalled and then proceed.
  • This might take quite some time!

 

Was this article helpful?
34 out of 50 found this helpful